徐州钢网架公司_小视频哪个网站比较好_成都网站优化及推广_软文营销的概念

目录

1）Unable to connect to adb.Check if adb is installed correctly

解决办法修改配置文件

2）Unexpected error while obtaining UI hierachy

解决办法替换文件

文件下载地址

1）Unable to connect to adb.Check if adb is installed correctly

解决办法修改配置文件

SDK根目录 === > tools ===> bin ===> uiautomatorviewer.bat ===> 鼠标右键以记事本打开 ==》找到platform-tools目录 ===》修改uiautomatorviewer.bat 文件中最后一行内容 ===》也就是下文中的标红的东西

你自己安卓SDK目录下的tools下的bin目录下的uiautomatorviewer.bat

@echo off
rem Copyright (C) 2012 The Android Open Source Project
rem
rem Licensed under the Apache License, Version 2.0 (the "License");
rem you may not use this file except in compliance with the License.
rem You may obtain a copy of the License at
rem
rem http://www.apache.org/licenses/LICENSE-2.0
rem
rem Unless required by applicable law or agreed to in writing, software
rem distributed under the License is distributed on an "AS IS" BASIS,
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
rem See the License for the specific language governing permissions and
rem limitations under the License.

rem don't modify the caller's environment
setlocal

rem Set up prog to be the path of this script, including following symlinks,
rem and set up progdir to be the fully-qualified pathname of its directory.
set prog=%~f0

rem Change current directory and drive to where the script is, to avoid
rem issues with directories containing whitespaces.
cd /d %~dp0

rem Get the CWD as a full path with short names only (without spaces)
for %%i in ("%cd%") do set prog_dir=%%~fsi

rem Check we have a valid Java.exe in the path.
set java_exe=
call ..\lib\find_java.bat
if not defined java_exe goto :EOF

for /f %%a in ("%APP_HOME%\lib\uiautomatorviewer-25.3.1.jar") do set jarfile=%%~nxa
set frameworkdir=.

if exist %frameworkdir%\%jarfile% goto JarFileOk
set frameworkdir=..\lib

if exist %frameworkdir%\%jarfile% goto JarFileOk
set frameworkdir=..\framework

:JarFileOk

set jarpath=%frameworkdir%\%jarfile%

if not defined ANDROID_SWT goto QueryArch
set swt_path=%ANDROID_SWT%
goto SwtDone

:QueryArch

for /f "delims=" %%a in ('%frameworkdir%\..\bin\archquery') do set swt_path=%frameworkdir%\%%a

:SwtDone

if exist "%swt_path%" goto SetPath
echo SWT folder '%swt_path%' does not exist.
echo Please set ANDROID_SWT to point to the folder containing swt.jar for your platform.
exit /B

:SetPath
set javaextdirs=%swt_path%;%frameworkdir%

call "%java_exe%" "-Djava.ext.dirs=%javaextdirs%" "-Dcom.android.uiautomator.bindir=D:\Programer\ProgramerUtil\AndroidStudioSDK\platform-tools" -jar %jarpath% %*